2.37. Wat is de verzuimfrequentie (incl. zwangerschapsverlof)?

Concepten

• Arbeidsovereenkomst
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Ziekteperiode
• Zorgkantoor regio
• Zwangerschapsverlof

Relaties

• deel van
• gaat over
• gedefinieerd door
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.37
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
7PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
8PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
9PREFIX onz-g: <http://purl.org/ozo/onz-g#>
10PREFIX onz-org: <http://purl.org/ozo/onz-org#>
11PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
12
13SELECT 
14	?Periode
15    (?vestiging AS ?Indeling)
16	(?zk_regio_code AS ?Zorgkantoorregio_code)
17    (COUNT(DISTINCT ?persoon) AS ?Aantal_personeelsleden_in_loondienst)
18    (SUM(?meldingen) AS ?Aantal_nieuwe_ziekmeldingen)
19    (IF(COUNT(DISTINCT ?persoon)=0,
20        "Ongedefinieerd",
21        (ROUND( ( (xsd:decimal(SUM(?meldingen)) / xsd:decimal(COUNT(DISTINCT ?persoon))) * 100.0 ) * 100.0 ) / 100.0)
22    ) AS ?Verzuimfrequentie_incl_zwangerschap)
23
24{
25    {
26        SELECT 
27        	?Periode
28        	?zk_regio_code
29            ?persoon
30            ?vestiging
31            (COUNT(DISTINCT ?ziekte) AS ?meldingen)
32        {
33	  		#BIND(2024 AS ?jaar)             
34          	VALUES ?kw { 1 2 3 4 0 }         
35
36          	# Periode-bepaling
37          	BIND( xsd:date(CONCAT(STR(?jaar), "-",
38                IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01","01-01"))))
39              )) AS ?start_periode )
40          	BIND( xsd:date(CONCAT(STR(?jaar), "-",
41                IF(?kw=1,"03-31", IF(?kw=2,"06-30", IF(?kw=3,"09-30","12-31")))
42              )) AS ?eind_periode)
43          	BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
44
45            ?overeenkomst 
46                a onz-pers:ArbeidsOvereenkomst ; # personeel in loondienst
47                onz-pers:heeftOpdrachtnemer ?persoon ;
48                onz-g:hasPart ?overeenkomst_afspraak .
49            ?overeenkomst_afspraak
50                a onz-pers:WerkOvereenkomstAfspraak ;
51                onz-g:isAbout ?locatie ;
52                onz-g:startDatum ?start_afspraak .
53            OPTIONAL {?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak}
54            FILTER (?start_afspraak <= ?eind_periode && ((!BOUND(?eind_afspraak)) || (?eind_afspraak >= ?start_periode)))
55			
56            OPTIONAL {
57                  VALUES ?type_verzuim {
58                    onz-pers:ZiektePeriode
59                    onz-pers:ZwangerschapsVerlof
60                  }
61
62                  ?ziekte
63                    a ?type_verzuim ;
64                    onz-g:definedBy ?overeenkomst ;
65                    onz-g:startDatum ?start_ziekte_periode .
66
67                  # Alleen nieuwe ziekmeldingen binnen meetperiode
68                  FILTER(?start_ziekte_periode >= ?start_periode && ?start_ziekte_periode <= ?eind_periode)
69
70                  # Zorg dat ziekmelding valt binnen looptijd van de afspraak 
71                  FILTER(?start_ziekte_periode >= ?start_afspraak && ( !BOUND(?eind_afspraak) || ?start_ziekte_periode <= ?eind_afspraak )
72                  )
73                }
74
75          {
76           # Tak 1: echte vestiging + afleiding zorgkantoorregio
77           ?locatie onz-g:partOf* ?vestiging_uri .
78           ?vestiging_uri a onz-org:Vestiging ;
79           onz-g:identifiedBy ?vest_nr ;
80           onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
81           ?vest_nr a onz-org:Vestigingsnummer ; onz-g:hasDataValue ?vestiging .
82
83           BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
84           ?pc_gebied onz-g:identifiedBy ?postcode ; onz-g:partOf+ ?zk_regio .
85           ?zk_regio a onz-org:ZorgkantoorRegio .
86           }
87           UNION
88           {
89           # Tak 2: totaal organisatie, laat ?zk_regio ongebonden (leeg in output)
90           ?locatie onz-g:partOf* ?vestiging_uri .
91           ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
92           BIND("Totaal organisatie" AS ?vestiging)
93           }
94
95           BIND(IF(BOUND(?zk_regio), STRAFTER(STR(?zk_regio), "/onz-org/"), ?unbound) AS ?zk_regio_code)
96        }
97        GROUP BY ?Periode ?persoon ?vestiging ?zk_regio_code
98    }
99}
100GROUP BY ?Periode ?vestiging ?zk_regio_code
101ORDER BY ?Periode ?vestiging 
102